Amiga Plus 1999 #2/Amiga Plus CD - 1999 - No. 2.iso/System-Boost/Workbench/LFSystemBinder/Install_LFSystemBinder21

Text File | 1998-06-21 | 5.6 KB | 190 lines

; Installation script for LFSystemBinder 2.1 (© LFSoft 1996)
;   15/08/1996 : Creation
;   16/11/1997 : Passage à la version 2.1
;
;   Note: The directory where this distribution reside must be LFSystemBinder2.1
; else this script can't found our custom icon for the new directory.
;

;
; Some checks about the system.
;

(set t (user 1)) ; Those warnings must be displayed even in 'Novice' mode.

(if (< (/ (getversion) 65536) 36)
    (
        (message "Sorry but LFSystemBinder 2.1 need at last 2.0 KickStart !")
        (exit (quiet))
    )
)

(if (< (/ (getversion "reqtools.library" (resident)) 65536) 38)
    (message "WARNING :\n\nreqtools.library 38+ is needed but can't be found on your system!\n\n"
            "Install this library or LFSystemBinder 2.0 will not work."
    )
)

(user t) ; Restore initial value

;
;   Install LFSB itself
;
(set name
    (askdir
        (prompt "Select the directory where LFSystemBinder2.1 will be installed.\n"
            "Note: The best thing may be to create a new directory."
        )
        (help @askdir-help)
        (default "sys:utilities/LFSystemBinder2.1")
    )
)

(set @default-dest name)

(if (exists "/LFSystemBinder2.1.info") ; Copy my custom icon
    (
        (run (cat "copy /LFSystemBinder2.1.info " @default-dest ".info")
            (prompt "\n\nCan I copy custom directory icon ?" )

            (help "This action will copy the drawer's icon of this distribution "
                "to the newly created directory.")
            (confirm)
        )
    )
)

(copyfiles
    (prompt "Select files to copy.\n"
        "Note: You'll be asked later for a working installation of all compagnons")
    (source "")
    (dest @default-dest)
    (help "If checked 'Examples' and 'Compagnons' directories will be copied in "
        '@default-dest' ". In all cases, you'll be asked latter if you want a working "
        "installation for each compagnons."
        "\n\n" @copyfiles-help
    )
    (choices "LFSystemBinder" "Examples" "compagnons" "Historique")
    (confirm)
    (infos)
)

(copyfiles
    (prompt "Select AmigaGuide Database you want to be installed.")
    (help "Those files are optionals but if you want extended help, you need at "
        "last your language documentation.\nSee the 'GUIDE' tools'type.\n\n"
        @copyfiles-help
    )
    (source "")
    (dest @default-dest)
    (pattern "#?.guide")
    (confirm)
    (infos)
)

(if (exists (cat @default-dest "/LFSystemBinder"))
    (
        (set t (user 1)) ; Only the user can say what he want
        (if
            (askbool
                (prompt "Which icon you want to be installed for LFSystemBinder ?")
                (choices "4 Colors icon" "8 Colors icons")
                (help "Choose the icon applicable to your Workbench:\n"
                    "4 colors icon is an icon suitable for all Workbench.\n"
                    "8 colors icon is an icon for at last 8 colored Workbench using "
                    "Magic Workbench palette.\n\n\n" @askbool-help
                )
            )

            (copyfiles
                (source "4colors.info")
                (dest @default-dest)
                (newname "LFSystemBinder.info")
                (help "")
            )
        )
        (user t) ; Restore initial value
    )
)

(copyfiles
    (prompt "Select catalogs needed.")
    (help "Those optional file allow LFSystemBinder to be localized.\n\n"
        @copyfiles-help
    )
    (source "catalogs")
    (dest (cat @default-dest "/Catalogs"))
    (all)
    (confirm)
    (infos)
)

(if (exists (cat @default-dest "/Catalogs"))
    (copyfiles
        (prompt "Copying file for 'Catalogs' directory icon.")
        (help "")
        (source "Catalogs.info")
        (dest @default-dest)
    )
)

;
;   Installation of LFSB complete,
;   now we're making a working installation of all compagnons...
;

;
;   Registry.library
;

(copylib
    (prompt "Copying 'registry.library' in 'libs:'\n\n"
        "Note: This library is required for enabling the 'interactive mode'."
        "On the other hand, LFSystemBinder will work without."
    )
    (source "compagnons/Registry/registry.library")
    (dest "libs:")
    (help @copylib-help)
    (confirm)
)

(copyfiles
    (prompt "Copying 'ListRegistry' to a directory in your PATH.\n\n")
    (source "compagnons/Registry/Compagons/ListRegistry")
    (dest "c:")
    (help "This tools is used to list the \"registry.library\"'s database.\n\n"
        "I'm sorry but Installer 1.24 doesn't find version's "
        "string of large executable so check yourself about version upgrade.\n\n" @copyfiles-help)
    (confirm)
)

(copyfiles
    (prompt "Copying 'Patch' to your WBStartup directory.\n\n")
    (source "compagnons/Registry/Compagons/PatchAssign")
    (dest "sys:WbStartup")
    (help "This tools allow notifications of some system datas (Assigns, Residents, Environmental variables and pathes)."
        "Note: If you use LFSystemBinder before the WorkBench is started, you may "
        "launch PatchAssign in your 'Startup-Sequence' (or your 'User-Startup') "
        "instead of in WBStartup.\n\n"
        "I'm sorry but Installer 1.24 doesn't find version's string of large "
        "executable so check yourself about version upgrade.\n\n" @copyfiles-help)
    (confirm)
    (infos)
)

;
;   Others
;

(copyfiles
    (prompt "Copying others goodies to a directory in your PATH.\n\n")
    (source "compagnons")
    (choices "LFGrabPath/LFGrabPath" "LFRxDirect/LFRxDirect")
    (dest "c:")
    (help "LFGrabPath and LFRxDirect have their own documentation file\n\n"
        "I'm sorry but Installer 1.24 doesn't find version's "
        "string of large executable so check yourself about version upgrade.\n\n" @copyfiles-help)
    (confirm)
    (infos)
)